Mindcode: a Mindustry Logic high-level language

Here you can compile a schematics definition written in Schemacode, a schema definition language, into a text representation to be pasted into Mindustry using the Import schematics... button. If your schematics contain processors, you can specify code for the processor using either Mindustry Logic or Mindcode. You can also decompile an existing schematics using the Decompiler and modify the resulting code.

Schemacode definition: Encoded schematic:

schematic
    name = "Item Transport"
    description = """
        Simple item transport schematics. Requires Mindustry BE.

Uses one of five predefined types of units for transport. Utilizes a separate processor
        and a new Mindcode remote call mechanism to switch to a more preferred unit type
        once it becomes available. The task to find a better unit runs in parallel on the second processor,
        allowing the item transport to run uninterrupted.
        """

@micro-processor     at ( 1,  0) processor
        links p0-* end
        mindcode = Main
    end
p0-processor1:
    @micro-processor     at ( 2,  0) processor
        links p1-* end
        mindcode = UnitMonitor
    end
p0-vault1:
    @vault               at ( 0,  1)
p0-sorter1:
    @sorter              at ( 0,  4)
p0-message1:
    @message             at ( 1,  4) text ""
p1-message1:
    @message             at ( 2,  4) text ""
end

UnitMonitor = """
    #set target = 8;
    #set syntax = strict;

module UnitMonitor;

linked message1;

require units;

// Unit types in preferred order
    // Change or add new units as necessary
    var types[5] = (@mega, @poly, @horizon, @flare, @mono);

// Tries to find a unit better than the one currently held (use null when no unit is held)
    // Returns when a unit is found.
    // Never returns if the best unit is already held.
    export def findUnit(currentUnit)
        var currentType = currentUnit.@type;
        print("Trying to find unit better than ", currentUnit);
        printflush(message1);
        while true do
            for var type in types do
                if type == currentType then break; end;
                print("Finding unit: ", type);
                printflush(message1);
                var unit = findFreeUnit(type, 0);
                if unit != null then
                    print("Returning unit: ", unit);
                    printflush(message1);
                    return unit;
                 end;
            end;
        end;
    end;
    """

Main = """
    #set target = 8;
    #set syntax = strict;

require "UnitMonitor" remote processor1;

// This declaration ensures all these blocks are available before the code continues
    linked sorter1, message1;
    linked storage = vault1;

// Unique flag to mark our units
    const FLAG = 1764335678894;

noinit var core;

// This is the main program body. Functions are defined below.
    begin
        message("Initializing...");
        do
            var unit = processor1.findUnit(null);

// Needs to bind the unit, it is bound by the remote processor at this moment
            ubind(unit);
            flag(FLAG);

// Core must always be here: if it is not, the unit is not functional
            core = ulocate(:building, :core, false);
        while core == null;

// Start searching for a better unit
        async(processor1.findUnit(@unit));

while true do
            moveItems();

// Try to see whether a better unit has been found
            if finished(processor1.findUnit) then
                // Obtain the result of the remote call
                var unit = await(processor1.findUnit);

// There might have been a delay: verify the unit is valid
                if !unit.@dead and (unit.@controller == processor1 or !unit.@controlled) then
                    // Free old unit
                    flag(null);
                    unbind();

// Switch to the new unit
                    ubind(unit);
                    flag(FLAG);
                end;

// Start looking again
                async(processor1.findUnit(@unit));
            end;
        end;
    end;

// Prints the message to message1
    void message(text)
        print(text);
        printflush(message1);
    end;

// If a unit is lost, restarts the entire program
    void checkUnit()
        if @unit.@dead or @unit.@controller != @this then
            end();
        end;
    end;

// Moves the unit to within 5 tiles from the building, waits till it gets there
    void moveTo(building)
        var x = building.@x;
        var y = building.@y;
        do
            approach(x, y, 5);
            checkUnit();
        while !within(x, y, 5);
    end;

// Returns false when unit is lost
    void moveItems()
        var capacity = @unit.@itemCapacity;
        var item;

message("Moving to core");
        moveTo(core);

do
            item = sorter1.@config;
            message(item == null ? "Please select item to transport" : "Taking items");

// If the unit carries incompatible items, drop them
            if @unit.@firstItem != null and @unit.@firstItem != item then
                itemDrop(@air, capacity);
            end;

itemTake(core, item, capacity);
            checkUnit();
        while @unit.@totalItems != capacity;

message("Moving to vault");
        moveTo(storage);

// Drop to storage. If the container is full, wait until it is possible to drop all
        // Stop trying when item selection changes
        message("Dropping items");
        do
            itemDrop(storage, capacity);
            checkUnit();
        while item == sorter1.@config and @unit.@totalItems > 0;
    end;
    """

182 lines of code

bXNjaAF4nF1UZ1RTaRq+hNB7LIgoXgQHRzALSDkIOLMgRSIBkSKDTLgkNySYxs1NlESKNBmkicKg1BEwBgSGIhIRlAUsQBBlEB0OOIwLFhARxB7ZG3Z39pw95/vxft/7PM/7fO0FVAE1VQDPgdgwoL8PhdlgMAJx+DwuggLaVC4HhTmoP8QDcOIEQIcG86kIk4cyuRyVoweZbB4LBplKDvpfDsinMmA2hDKpfCIYBMcJmAjMB/2ZHJqAjyLxoIcXUTuEjy1xOTDIpYN0phAGeQhMg+lMDkwD0XieMkkHBRwmygfpXOR/2kQwBGWymCIMAIF8mAchEKokc6kwn48BIQ4NS3Dgo6v1qFwaDCIwm4thqBCLBbJhKgPiMPmYWy7IP8pEqQxlBIFsLrLqgQ4jmJHVyqs+MI9U5f7AaJjKZSurCiEmC4pmwUQwmAGDKMQ/olTAnCsLR8MoCiP/piMCDh9kckClRxYLZmFSIIpR+JgSBv7Lsw2IpblHmZyY1fT/nSWmjQkpFbFrQBABD4VpRDxgwGZSEe7Ov0QANSEkYKGAOhZjOEAD88qHYmAAANQBQAUA9AFAFT1WOhpK4ozbGgqyLuxMM0sZtv9+kwIWw+CrraeAyGqNym2/00kHdni5xBk8OlJjkZXdxbnOMFo7uaHUOW8XN6NKVizf85WAlzwPoqef0j5tVW3Dn9r6ubnaNRfelslOqGvGuWQ+W1zK096V0zbCSN1s9eaLnvlA1GyjfgN7XQry01wEeVtf9tfq484V95Y/FoVMm8E8jUmjMZFhMKHX+pYorLHtrIRyIqow2MOQOLvS5s21s77r8IXwdRgJCEp9FdNKXswibb2ZJd1LlCGesy7iFS9yjUf2nRZ84pr9PU21QEKKp2H8zcG2Wr1SB986P4ToNTRcNLUZebp9QWGbZXwKBoLqKkKa3Lrzb1+8YKNmfqBApwqgHVy7lzF3vc3BSH23h6C6dzT2coDPh8Y0otZJi9b+RVVZoaV1mBaR5zF9wKdF/fWcd8W5SdmAgaDZPuwj+Sr55497KO4v0bE8z4H7h3Lr/9mezItrft1+dSFwX2P4S3uNci2ndI/3Nl1NDLp3WqGx4iQBf++QTAKzned/meLy/BXHJSPRAFOUvdCas3ICt+Y7o04kwkM7S77UwSLJnRpIkRr4mECnsJqWGtdku4I7M7KSto2fLo0dSYLwnlcZGnDy4r4T8eGANGdO/KWTGMveIT/LyFwJpqRr5vRH7PALf+JOeJyjG+x4fMx1T48Yqkydi7XsOXzvNvy6Nj2RE3ki0mKBL40tCsAxHhaTv8MrfuvQr1x3n+169jO+x/rdkWPNFFdncYMsfIawqzCZc7QxyR20QjblZag2FLvxnbZfdnXZlP0i6Zz+6RVniecGf3+NesFEW9+CXL/a7L1s/VtUcqNcGMcjSz5V2Wler68wzp6kPX1ooWX1+2aG8NcdwLLCbEnd2KR9xNTxR9Z8bOC1d2/+kPZOqO0tsxkaj476Q2D/A+P83St3XPLipgTGFjGtJvIJY2FVrsiWkB0wsqET96FLZbkLfmnD2Pw5YSTOQK81R3LbyJ+n65mp16r1C9st6X6H5XzIKOUdYXhL/nTzgNun5EvLgQm0sinJhT9jK9AfSB2UoYkWp8GwcV1/0+h3yXk1WV55ZSVu1tt9c518UI3WfeUENF1oO1qrd3xtyyz+1Fn7/OXdI8Lx83I6NyZUPDaHI0869mh+7TzXOdb46YVW8pZBoG4iUfXGpygX7AfiVr8fjnqsVB7mn1diayj3cw92eeucjWT/Fqk7lyHXkr6cFEnbnvXfTGu3d3Kkh72oeEHZuSUjP40TFC4NJNqazbjfiNcdkrPeTb3Psx/oVuunvGgANErj15gP2QZXZkR0DjQd2m1IL34AZX5fTOoyzTiseTWoiRKkW2WWZkpep09NDAnQfpxWpEZSG63xOGRpYCQofbS8tdcn6Wk95U70V79z6im97H3qJzd5ma+77Lzf8gl+ZLY9WDs9sSGKXLXsmOaYHt9QPPzrsVDXb4KGCS8Pb59N07zirSYiqdns/5MhFbJ7BqJ1TNar+Z/eYJ5ws2LbtFjhbSK0Ka+9ct5b78a8XUeMD9R/aWZc0qon+LuvQqaiX1KfWbAUSiubThSPV4sm4ySmKQHaTeYyqHb4SclG/xry82tD/WsNqN+2FpRSoxdS3RNLng+SzuALNR5svKzQ872y7BO+nN8bn0pJcZAWuNzizuHEoSE7o4ULV+fiBJ2K+aEsxwsfnianhtu+Wskq/NwnVTk/eH/+vV7dm5+1l0lhjz7c0yFT5i0CCDoBBUvlDtyUG9cenXnfvc4t/nW4aLF41MHtsdT0UPxid0WxVaROwLVn7swusG7gGY2X4yJrLjtz+/LFqbvkyA4Xk/1ssmh9+dsh8YMjB7b8reJMr+xWpWXuq2q3KUe9CCFuPMfP46KTdYIOJbdld349ddHgpB9SeHBb057Q8oXzGXbi9FfqMyv2M1NBgu6snd9UhvxkkTSomxpgPxA+6pcpXKgRORVp/cPH99xk0X22TUtHcW1aHLkvkv7QeOkxS7hL/OR07fykQmWiT6sRa/UqyveGDQCPtXxshsdj7R+LcP+J/gXamIc+

Bug reports, suggestions and questions are welcome at the project page.

Build messages:

Compiling embedded code
133 instructions before optimizations.
7 instructions eliminated by Temp Variables Elimination (2 passes, 5 iterations).
8 instructions eliminated by Dead Code Elimination (4 iterations).
1 instructions eliminated by Jump Normalization (4 iterations).
4 instructions eliminated by Jump Optimization (4 iterations).
4 instructions eliminated by Single Step Elimination (5 iterations).
3 instructions eliminated by If Expression Optimization (3 iterations).
7 instructions eliminated by Data Flow Optimization (3 passes, 12 iterations).
1 loops improved by Loop Hoisting.
5 instructions added by Function Inlining (6 iterations).
10 function calls inlined by Function Inlining.
1 instructions updated by Jump Threading.
1 instructions eliminated by Unreachable Code Elimination (2 iterations).
103 instructions after optimizations.
Code size and number of instantiations by function: Size Times AvgSize Function 40 1x 40.0 <no function> 24 4x 6.0 void checkUnit() 20 1x 20.0 void moveItems() 10 5x 2.0 void message(in text) 10 2x 5.0 void moveTo(in building)
Performance: parsed in 23 ms, compiled in 8 ms, optimized in 62 ms.
Compiling embedded code
91 instructions before optimizations.
2 instructions eliminated by Temp Variables Elimination (6 iterations).
10 instructions eliminated by Dead Code Elimination (5 iterations).
1 instructions eliminated by Jump Normalization (5 iterations).
6 instructions eliminated by Jump Optimization (5 iterations).
10 instructions eliminated by Single Step Elimination (3 passes, 8 iterations).
1 instructions eliminated by If Expression Optimization (4 iterations).
9 instructions eliminated by Data Flow Optimization (2 passes, 8 iterations).
102 instructions added by Loop Unrolling (4 iterations).
1 loops unrolled by Loop Unrolling.
5 instructions eliminated by Jump Straightening (5 iterations).
6 instructions updated by Jump Threading.
9 instructions eliminated by Unreachable Code Elimination (2 iterations).
140 instructions after optimizations.
Code size and number of instantiations by function: Size Times AvgSize Function 75 5x 15.0 def findFreeUnit(in unit_type, in initial_flag) 56 1x 56.0 export def findUnit(in currentUnit) 10 1x 10.0 <no function>
Performance: parsed in 28 ms, compiled in 8 ms, optimized in 29 ms.
Created schematic 'Item Transport' with dimensions ( 3, 5).

Mindcode Compiler Mlog Decompiler Schematics Builder Schematics Decompiler

Mindcode Compiler
Mlog Decompiler
Schematics Builder
Schematics Decompiler